**Grammer**

PROG -> GLOBAL\_VARS FUNC\_PREDEFS FUNC\_FULL\_DEFS

GLOBAL\_VARS -> VAR\_DEC GLOBAL\_VARS'

GLOBAL\_VARS' -> ε | VAR\_DEC GLOBAL\_VARS'

VAR\_DEC -> TYPE id VAR\_DEC'

VAR\_DEC' -> ; | [ DIM\_SIZES ] ;

TYPE -> int | float

DIM\_SIZES -> int\_num DIM\_SIZES'

DIM\_SIZES' -> ε | , DIM\_SIZES

FUNC\_PREDEFS -> FUNC\_PROTOTYPE ; FUNC\_PREDEFS'

FUNC\_PREDEFS' -> ε | FUNC\_PROTOTYPE ; FUNC\_PREDEFS'

FUNC\_PROTOTYPE -> RETURNED\_TYPE id ( PARAMS )

FUNC\_FULL\_DEFS -> FUNC\_WITH\_BODY FUNC\_FULL\_DEFS'

FUNC\_FULL\_DEFS' -> ε | FUNC\_FULL\_DEFS

FUNC\_WITH\_BODY -> FUNC\_PROTOTYPE COMP\_STMT

RETURNED\_TYPE -> TYPE | void

PARAMS -> PARAM\_LIST | ε

PARAM\_LIST -> PARAM PARAM\_LIST'

PARAM\_LIST' -> ε | , PARAM PARAM\_LIST'

PARAM -> TYPE id PARAM'

PARAM' -> ε | [ DIM\_SIZES ]

COMP\_STMT -> { VAR\_DEC\_LIST STMT\_LIST }

VAR\_DEC\_LIST -> ε | VAR\_DEC VAR\_DEC\_LIST

STMT\_LIST -> STMT STMT\_LIST'

STMT\_LIST' -> ε | ; STMT STMT\_LIST'

STMT -> id STMT' | COMP\_STMT | IF\_STMT | RETURN\_STMT

STMT' -> VAR' = EXPR | ( ARGS )

IF\_STMT -> if ( CONDITION ) STMT

CALL -> id ( ARGS )

ARGS -> ARG\_LIST | ε

ARG\_LIST -> EXPR ARG\_LIST'

ARG\_LIST' -> ε | , EXPR ARG\_LIST'

RETURN\_STMT -> return RETURN\_STMT'

RETURN\_STMT' -> ε | EXPR

VAR -> id VAR'

VAR' -> ε | [ EXPR\_LIST ]

EXPR\_LIST -> EXPR EXPR\_LIST'

EXPR\_LIST' -> ε | , EXPR EXPR\_LIST'

CONDITION -> EXPR rel\_op EXPR

EXPR -> TERM EXPR'

EXPR' -> ε | + TERM EXPR'

TERM -> FACTOR TERM'

TERM' -> ε | \* FACTOR TERM'

FACTOR -> id FACTOR' | int\_num | float\_num | ( EXPR )

FACTOR' -> ε | [ EXPR\_LIST ] | ( ARGS )

**Nullable, First and Follow**

|  |  |  |  |
| --- | --- | --- | --- |
| **Symbol** | **Nullable** | **First** | **Follow** |
| PROG | X | float int | $ |
| GLOBAL\_VARS | X | float int | float int void |
| GLOBAL\_VARS' | V | float int | float int void |
| VAR\_DEC | X | float int | float id if int return void { |
| VAR\_DEC' | X | ; [ | float id if int return void { |
| TYPE | X | float int | id |
| DIM\_SIZES | X | int\_num | ] |
| DIM\_SIZES' | V | , | ] |
| FUNC\_PREDEFS | X | float int void | float int void |
| FUNC\_PREDEFS' | V | float int void | float int void |
| FUNC\_PROTOTYPE | X | float int void | ; { |
| FUNC\_FULL\_DEFS | X | float int void | $ |
| FUNC\_FULL\_DEFS' | V | float int void | $ |
| FUNC\_WITH\_BODY | X | float int void | $ float int void |
| RETURNED\_TYPE | X | float int void | id |
| PARAMS | V | float int | ) |
| PARAM\_LIST | X | float int | ) |
| PARAM\_LIST' | V | , | ) |
| PARAM | X | float int | ) , |
| PARAM' | V | [ | ) , |
| COMP\_STMT | X | { | $ ; float int void } |
| VAR\_DEC\_LIST | V | float int | id if return { |
| STMT\_LIST | X | id if return { | } |
| STMT\_LIST' | V | ; | } |
| STMT | X | id if return { | ; } |
| STMT' | X | ( = [ | ; } |
| IF\_STMT | X | if | ; } |
| CALL | X | id |  |
| ARGS | V | ( float\_num id int\_num | ) |
| ARG\_LIST | X | ( float\_num id int\_num | ) |
| ARG\_LIST' | V | , | ) |
| RETURN\_STMT | X | return | ; } |
| RETURN\_STMT' | V | ( float\_num id int\_num | ; } |
| VAR | X | id |  |
| VAR' | V | [ | ) \* + , ; = ] rel\_op } |
| EXPR\_LIST | X | ( float\_num id int\_num | ] |
| EXPR\_LIST' | V | , | ] |
| CONDITION | X | ( float\_num id int\_num | ) |
| EXPR | X | ( float\_num id int\_num | ) , ; ] rel\_op } |
| EXPR' | V | + | ) , ; ] rel\_op } |
| TERM | X | ( float\_num id int\_num | ) + , ; ] rel\_op } |
| TERM' | V | \* | ) + , ; ] rel\_op } |
| FACTOR | X | ( float\_num id int\_num | ) \* + , ; ] rel\_op } |
| FACTOR' | V | ( [ | ) \* + , ; ] rel\_op } |